Adding basic car

2026-01-21 17:59:14 -06:00
parent 900951b1a7
commit 582b2c43cb
14 changed files with 452 additions and 279 deletions
@@ -0,0 +1,81 @@
+extends RigidBody3D
+
+@export var drive_speed := 18.0
+@export var drive_accel := 20.0
+@export var brake_strength := 28.0
+@export var turn_speed := 2.0
+@export var turn_accel := 8.0
+@export var lateral_damp := 10.0
+@export var seat_path: NodePath
+@export var exit_path: NodePath
+@export var camera_path: NodePath
+@export var interact_area_path: NodePath
+
+@onready var seat: Node3D = get_node(seat_path) if seat_path != NodePath("") else null
+@onready var exit_point: Node3D = get_node(exit_path) if exit_path != NodePath("") else null
+@onready var car_camera: Camera3D = get_node(camera_path) if camera_path != NodePath("") else null
+@onready var interact_area: Area3D = get_node(interact_area_path) if interact_area_path != NodePath("") else null
+
+var _nearby_driver: Node = null
+var _driver: Node = null
+
+func _ready() -> void:
+	if interact_area:
+		interact_area.collision_layer = 2
+		interact_area.collision_mask = 1
+		interact_area.body_entered.connect(_on_interact_body_entered)
+		interact_area.body_exited.connect(_on_interact_body_exited)
+	if car_camera:
+		car_camera.current = false
+
+func _process(_delta: float) -> void:
+	if _driver == null and _nearby_driver != null and Input.is_action_just_pressed("interact"):
+		_enter_vehicle(_nearby_driver)
+	elif _driver != null and Input.is_action_just_pressed("interact"):
+		_exit_vehicle()
+
+func _integrate_forces(state: PhysicsDirectBodyState3D) -> void:
+	if _driver == null:
+		return
+
+	var input2v := Input.get_vector("ui_left", "ui_right", "ui_up", "ui_down")
+	var forward := global_transform.basis.z
+	forward.y = 0.0
+	forward = forward.normalized()
+
+	var current_speed := linear_velocity.dot(forward)
+	var target_speed := input2v.y * drive_speed
+	var accel := drive_accel if abs(input2v.y) > 0.01 else brake_strength
+	var new_forward_speed := move_toward(current_speed, target_speed, accel * state.step)
+	var forward_vel := forward * new_forward_speed
+	var lateral_vel := linear_velocity - (forward * current_speed)
+	lateral_vel = lateral_vel.move_toward(Vector3.ZERO, lateral_damp * state.step)
+	linear_velocity = forward_vel + lateral_vel
+
+	var speed_factor: float = clamp(abs(new_forward_speed) / drive_speed, 0.0, 1.0)
+	var target_turn: float = -input2v.x * turn_speed * speed_factor
+	angular_velocity.y = move_toward(angular_velocity.y, target_turn, turn_accel * state.step)
+
+func _enter_vehicle(player: Node) -> void:
+	if seat == null:
+		return
+	_driver = player
+	player.call("enter_vehicle", self, seat, car_camera)
+	if car_camera:
+		car_camera.current = true
+
+func _exit_vehicle() -> void:
+	if _driver == null:
+		return
+	_driver.call("exit_vehicle", exit_point, car_camera)
+	_driver = null
+	if car_camera:
+		car_camera.current = false
+
+func _on_interact_body_entered(body: Node) -> void:
+	if body.has_method("enter_vehicle"):
+		_nearby_driver = body
+
+func _on_interact_body_exited(body: Node) -> void:
+	if body == _nearby_driver:
+		_nearby_driver = null