Add user progress dashboard

scripts/autoload/dashboard_service.gd

@@ -0,0 +1,60 @@
+extends Node
+
+signal dashboard_changed
+signal dashboard_failed(message: String)
+
+const EndpointConfig := preload("res://scripts/autoload/api_endpoint_config.gd")
+const DEFAULT_URL := "https://s3q.ranaze.com/api/dashboard"
+
+var data: Dictionary = {}
+var loading := false
+var request: HTTPRequest
+var request_token := ""
+var api_url := DEFAULT_URL
+
+
+func _ready() -> void:
+	api_url = EndpointConfig.resolve(
+		str(ProjectSettings.get_setting("step3/dashboard_api_url", DEFAULT_URL)),
+		"/api/dashboard")
+	request = HTTPRequest.new()
+	request.timeout = 20.0
+	request.request_completed.connect(_on_completed)
+	add_child(request)
+	AuthState.auth_changed.connect(_on_auth_changed)
+
+
+func refresh() -> void:
+	if loading or not AuthState.can_send_authenticated_request():
+		return
+	loading = true
+	request_token = AuthState.access_token
+	var headers := PackedStringArray(["Authorization: Bearer %s" % request_token])
+	var error := request.request(api_url, headers, HTTPClient.METHOD_GET)
+	if error != OK:
+		loading = false
+		dashboard_failed.emit("Dashboard data could not be loaded. Check your connection and try again.")
+
+
+func _on_completed(result: int, response_code: int, _headers: PackedStringArray, body: PackedByteArray) -> void:
+	loading = false
+	if response_code == 401:
+		AuthState.handle_unauthorized(request_token)
+		return
+	if result != HTTPRequest.RESULT_SUCCESS or response_code < 200 or response_code >= 300:
+		dashboard_failed.emit("Dashboard data could not be loaded. Check your connection and try again.")
+		return
+	var parsed: Variant = JSON.parse_string(body.get_string_from_utf8())
+	if typeof(parsed) != TYPE_DICTIONARY:
+		dashboard_failed.emit("The dashboard service returned an invalid response.")
+		return
+	data = parsed
+	dashboard_changed.emit()
+
+
+func _on_auth_changed() -> void:
+	if not AuthState.is_logged_in:
+		data = {}
+		loading = false
+		if request.get_http_client_status() != HTTPClient.STATUS_DISCONNECTED:
+			request.cancel_request()

scripts/autoload/dashboard_service.gd.uid

@@ -0,0 +1 @@
+uid://c8nmhxwb875uy

scripts/autoload/question_bank_service.gd

@@ -257,10 +257,10 @@ func clear_questions() -> void:
 	ratings_changed.emit()
 
 
-func record_first_attempt(question_id: String, choice_id: String, presented_choice_ids: Array = []) -> void:
+func record_first_attempt(question_id: String, choice_id: String, presented_choice_ids: Array = [], duration_seconds: int = 0) -> void:
 	if not AuthState.can_send_authenticated_request() or question_id == "" or choice_id == "":
 		return
-	_enqueue_attempt("answer", question_id, choice_id, presented_choice_ids)
+	_enqueue_attempt("answer", question_id, choice_id, presented_choice_ids, duration_seconds)
 
 
 func skip_question(question_id: String) -> void:
@@ -386,7 +386,7 @@ func _on_retry_timer_timeout() -> void:
 	load_questions_from_api(false)
 
 
-func _enqueue_attempt(kind: String, question_id: String, choice_id: String, presented_choice_ids: Array = []) -> void:
+func _enqueue_attempt(kind: String, question_id: String, choice_id: String, presented_choice_ids: Array = [], duration_seconds: int = 0) -> void:
 	var account := AuthState.username.strip_edges()
 	if account == "":
 		return
@@ -399,6 +399,7 @@ func _enqueue_attempt(kind: String, question_id: String, choice_id: String, pres
 		"question_id": question_id,
 		"choice_id": choice_id,
 		"presented_choice_ids": presented_choice_ids.duplicate(),
+		"duration_seconds": maxi(0, duration_seconds),
 		"retry_count": 0
 	})
 	_save_attempt_queue()
@@ -430,7 +431,8 @@ func _process_attempt_queue() -> void:
 	var body := JSON.stringify({
 		"questionExternalId": question_id,
 		"choiceId": str(queued.get("choice_id", "")),
-		"presentedChoiceIds": queued.get("presented_choice_ids", [])
+		"presentedChoiceIds": queued.get("presented_choice_ids", []),
+		"durationSeconds": int(queued.get("duration_seconds", 0))
 	})
 	if str(queued.get("kind", "answer")) == "skip":
 		url = "%s/%s/skip" % [question_api_base_url.rstrip("/"), question_id.uri_encode()]